第10章 ABAP入門基本要點
· ABAP 的一些基本注意事項：
https://blog.csdn.net/szlaptop/article/details/8465103
https://blog.csdn.net/weixin_38500922/article/details/96423835
https://noahchou.wordpress.com/2011/11/17/abap%e7%a8%8b%e5%bc%8f%e5%9f%ba%e6%9c%ac%e8%aa%9e%e6%b3%95%e5%92%8c%e6%a0%bc%e5%bc%8f/

[bookmark: _GoBack]https://www.itread01.com/content/1548803704.html

在第一章中，我們有簡單的說明ABAP在SAP的地位及重要性，如果想要邁進ABAP的大門，你至少需要了解下面幾個方面，特別說明，ABAP是完整的開發工具，本文只是簡單的介紹一些觀念重點，並不是短期快速入門的內容：
一、關於符號和字母,記住下面這幾點，你程式的小錯誤基本減少99%
· 語句結束用"."。
· 沒有雙引號只有單引號。Error Exp: WRITE "AAA".
· 一些保留字元需要單引號括起來，比如.等。Error Exp: a = 1.7
· 運算子前後有空格，也就是=/+等這些前後一定要有空格。Error Exp: a=b
· 雖然abap不區分大小寫，但是這個也是一個傳說.....，你還是儘量全部大寫！特別是功能碼、欄位名等。
· 整行註釋用 * ,語句註釋用“，多行批量註釋與反註釋: ctrl+,  ctrl+.
· 自己寫的程式(含新增的 Table、View等)，只能以z和y開頭
· / 表示換行
二、基本的語法語句: 字元操作、邏輯迴圈....簡單說明如下
    宣告語句：TYPES、DATA、PARAMETERS、TABLES
    基本操作：WRITE、MOVE
    字元操作：CONCATTENATE、SPLIT、CONDENSE、SEARCH、REPLACE、TRANSLATE
    邏輯迴圈：IF、WHILE、CASE、DO   (迴圈完全中止exit,條件終止 check +exit ,迴圈內中止continue)
    呼叫語句：PERFORM, CALL, SUBMIT, LEAVE TO 
    函式定義： FORM/ENDFORM, FUNCTION/ENDFUNCTION, MODULE/ENDMODULE
    比較運算：=、<>.......
三、資料型別：
    常用的C（文字）、I（整數）P和F（小數）、N（可把數值作為文字）、X （16進位制）、D（日期）
四、SAP的開發大多數情況都是訪問資料，所以你需要清楚瞭解一下內表(internal Table)：
    關於 Internal Table 請參考上一節的詳細說明(非常重要)。               
五、熟悉運用以下的系統定義的常用變量
    SY-SUBRC=0表示找到記錄，sy-dbcnt表示找到的記錄數量。
　　SY-DBLNT: 被處理過的記錄的筆數
　　SY-UNAME: 當前使用者登入SAP的USERNAME
　　SY-DATUM: 當前系統日期
　　SY-UZEIT: 當前系統時間
　　SY-TCODE: 當前執行程式的Transaction code
　　SY-INDEX : 當前LOOP迴圈過的次數
　　SY-TABIX: 當前處理的是internal table 的第幾筆
　　SY-TMAXL: Internal table的總筆數
　　SY-MANDT: SAP的Client ID
　　SPACE: 空字串
六、SAP的二次開發大多是操作資料，而那些資料都是存放在資料庫裡面，ABAP語法有透過Open SQL直接整合常用的SQL語法，方便開發人員存取資料內容，Open SQL的語法近似標準SQL，但功能較陽春，Open SQL的優點是不必針對不同的資料庫撰寫不同的SQL語法，它會自動將Open SQL轉為各DB能執行的語法，也因為如此，所以提供的功能當然就會較陽春，不過根據我的自學過程看來，忍一忍還是可用，況且，ABAP還是提供EXEC語法，還是可以針對特定資料庫直接下命令。   
Open SQL 稍後會有專章說明。

ABAP開發內容主要為報表、螢幕、表單、增強、接口(轉分享SAP癡貨的ABAP學習地圖)
· 報表：輸出用戶指定需求的數據信息。像在財務工作中經常使用的現金流量表、資產負債表、損益表。這裡主要需要掌握數據結構定義、資料庫操作、內表操作、ALV（輸出顯示用）等。
· 螢幕：輸入輸出數據，實現與用戶的互動。主要需要掌握螢幕流原理。
· 表單：將實際工作中需要列印的表格在SAP裡面進行實現。主要需要掌握Smartform。
· 增強：SAP提供的標準功能不能夠完全覆蓋每家企業的實際業務。SAP針對這一現象，對它的標準功能預留了一些接口，我們通過這些接口技術來實現企業獨特的業務需求。這裡主要需要掌握出口、BADI、增強點技術。
· 接口：實現SAP間、SAP與其他軟體間的一種數據交互。如汽車生產廠商向零部件生產商進行訂貨。這裡主要是RFC、IDOC、Webservice等。


我個人認為，看範例學程式是最有效率的，所以接下來，就由淺入深的多支範例程式來開始ABAP的學習之旅
以下是第一支代表性的報表程式，可以讓有程式設計基礎的開發人員能一眼就明瞭ABAP的基本架構。

	*&---------------------------------------------------------------------*
*& Report ZMC001
*&---------------------------------------------------------------------*
REPORT ZMC001.
TYPE-POOLS: slis.

DATA itab TYPE TABLE OF zmm011_t01 WITH HEADER LINE.

PARAMETERS:
  p_grid RADIOBUTTON GROUP rg1 DEFAULT 'X',
  p_list RADIOBUTTON GROUP rg1.

SELECT-OPTIONS:
  d_BLDAT FOR itab-BLDAT.

START-OF-SELECTION.
  SELECT * INTO TABLE @itab FROM zmm011_t01 UP TO 100 ROWS
    where BLDAT in @d_BLDAT.

CASE 'X'.
  WHEN p_grid.
    CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  exporting
    I_STRUCTURE_NAME            =     'zmm011_t01'  " Internal output table structure
    T_OUTTAB                    =      itab.            " Table with data to be displayed
  WHEN p_list.
    CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
  exporting
    I_STRUCTURE_NAME            =     'zmm011_t01'  " Internal output table structure
    T_OUTTAB                    =      itab.            " Table with data to be displayed
  WHEN OTHERS.
ENDCASE.





前頁的程式按F8 後執行的畫面
[image: ]
選 P_GRID 後的報表執行畫面(日期輸入 20190505)
[image: ]
選 P_LIST 後的報表執行畫面(日期輸入 20190505)
[image: ]
有程式開發經驗的童鞋，應該一眼就理解上面這支程式的架構寫法

· Line1-Line3 程式的註解，在ABAP中，行開始處輸入星號（*）或是要將某行的一部分變為注解，則在注解之前輸入雙引號（"）即可。ABAP句尾固定是用句號當作是一行指令的結束，習慣就好。
· Line 4 是本報表的名稱，一定要是 REPORT 開頭
· Line 7 宣告一個 DataSet (內表，InternalTable)
· Line9-Line11 報表的輸入條件參數宣告(單純的 text)
· Line13-Line14 SELECT-OPTIONS 報表變數宣告，支援開窗查詢功能
· Line16 START-OF-SELECTION ABAP 程式的開始執行點，類似 Java 的 main()
· Line17-Line18 取得報表要顯示的資料，並寫到 DataSet(內表) 中
· Line20-Line32 是一個 case when 判斷程式，根據 PARAMETER 的輸入，決定要執行哪一段程式
· Line22-Line25 呼叫 ABAP 內建的 FunctionModules，執行報表的顯示。類似將取得的 DataSet 資料，綁定到 ABAP 的 DataGrid 顯示元件。
· Line27-Line30 同上

通過上面這支簡單的範例說明，就可以了解要如何完成一張報表的基本架構。除了宣告的變數較特殊外，基本上和傳統程式差異不大。因為ABAP是一個完全獨立的開發語言，自成一個開發體系，所以要深入了解，就必須繼續研讀相關的文件(例如下面的這些 Function Modules 要如何使用?) 並多看相關的範例程式碼。除了報表外，ABAP也可以開發表單程式，但這是 another story 了。
[image: ]


· 關於 Internal Table 下面有一個 Sample 簡單的說明其觀念
Internal Table 是一種Data Structure(數據結構)，類似於其它語言中的Structure，Internal Table與資料結構體基本類似，它同樣是程式執行中被創建的一個存儲空間，它是一個可包含多條記錄的資料表，它可以由幾個不同類型的字段(field)組成，用來表示具有不同屬性的某一事物，單獨一筆數據表示某個事物，多筆數據表示具有相同屬性的多個事物。

Internal Tables共有以下3 種類型。
· Standard
· Sorted
· Hashed
[image: ]

	PROGRAM demo_internal_table.

TYPES: BEGIN OF mytext,
         number TYPE i,
         name(10) TYPE c,
       END OF mytext.

TYPES mytab TYPE STANDARD TABLE OF mytext WITH DEFAULT KEY.
DATA text TYPE mytext.
DATA itab TYPE mytab.
text-number = 1. text-name = 'John'.
APPEND text TO itab.
text-number = 2. text-name = 'Paul'.
APPEND text TO itab.
text-number = 3. text-name = 'Ringo'.
APPEND text TO itab.

LOOP AT itab INTO text.
  WRITE: / text-number,text-name.
ENDLOOP.


第3、6行 使用BEGIN-END 宣告一個資料結構，結構體名稱為：mytext，該結構體有number,name 共2個欄位
第8行 使用TYPES 指令建立一個Internal Table ；類型為Standard ；參考的資料結構體為mytext ；通過關鍵字：DEFAULT KEY指定預設字段為key列，對於Standard tables，預設的key列是由所有CHAR-LIKE字段組成的(C,N,D,T,X,STIRNG,XSTRING)
第9行 使用DATA 宣告變數，名稱為：text、類型引用自行定義資料類型：mytext
第10行 使用DATA 宣告變數，名稱為：itab、類型引用自行定義資料類型：mytab
第11、16行 將資料賦值給text(結構體)後再透過APPEND指令將text(結構體)的資料寫入itab(Internal Table )
第18、20行 透過LOOP指令將itab(Internal Table )內容印出至螢幕。

一開始看第一支範例程式時，看到 Line7
DATA itab TYPE TABLE OF zmm011_t01 WITH HEADER LINE.
可能會有一個誤解，會誤以為如果要顯示報表的資料，就要先在 se11 中定義 DataElement才行。

但是透過上面的程式，對Internel Table 就更理解並非如此，只需在程式中用 TYPES 定義一個 Structure，然後用 DATA 定義 TYPE OF TABLE就可以在 Report 中使用 Internal Table，這就符合一般程式中可以動態建立Client端的暫存表(Internal Table) 用來暫存計算並顯示相關資料，並綁定元件顯示的標準做法。

http://www.sapjx.com/alv-fieldcat-and-layout.html

	*&---------------------------------------------------------------------*
*& Report ZMC002
*&---------------------------------------------------------------------*
*& 改寫用自定義的 Types 取代 DataElement
*& 並練習寫 FORM (function)
*&---------------------------------------------------------------------*
REPORT ZMC002.

TYPE-POOLS: slis.

TYPES: BEGIN OF sumReport,
         "BILLDATE TYPE d,
         BLDAT TYPE d,
         BWART(10) TYPE c,
         WERKS(10) TYPE c,
         QTY TYPE i,
         RECNO TYPE i,
       END OF sumReport.

TYPES tpl_tab TYPE STANDARD TABLE OF sumReport WITH DEFAULT KEY.
DATA itab TYPE tpl_tab WITH HEADER LINE.
DATA wa_data LIKE LINE OF itab.

DATA: wa_fieldcat TYPE slis_fieldcat_alv ,    " 相当于工作区
      i_fieldcat  TYPE slis_t_fieldcat_alv ,  " 存放列名的列表
      i_layout    TYPE slis_layout_alv .      " 负责整个ALV的全局属性

i_layout-zebra                  = 'X' .          " 使ALV界面呈现颜色交替
"i_layout-colwidth_optimize      = 'X' .          " 自动优化列宽
"i_layout-detail_initial_lines   = 'X' .          " 是否出现细节屏幕
"i_layout-detail_titlebar        = '详细内容' .   " 细节屏幕标题

PARAMETERS:
  p_grid RADIOBUTTON GROUP rg1 DEFAULT 'X',
  p_list RADIOBUTTON GROUP rg1,
  p_write RADIOBUTTON GROUP rg1.

SELECT-OPTIONS:
  d_BLDAT FOR itab-BLDAT.

START-OF-SELECTION.
  "設定 alv 參數
  PERFORM frm_set_fieldcat  USING:
  'ITAB'  'BLDAT'   '文件日期' '日期'  'X',
  'ITAB'  'BWART'   '異動類別' '異動類別' '',
  'ITAB'  'WERKS'   '倉庫代號' '倉庫' '',
  'ITAB'  'QTY'   '數量合計' '數量' '',
  'ITAB'  'RECNO'   '總筆數' '總筆數' ''.

  "取得資料
  SELECT BLDAT,BWART,WERKS,sum( MENGE ) AS QTY,count( * ) AS RECNO INTO TABLE @itab
    FROM  zmm011_t01
    "UP TO 1000 ROWS
    group by BLDAT,BWART,WERKS
    HAVING BLDAT in @d_BLDAT
  ORDER BY BLDAT,BWART,WERKS.

CASE 'X'.
  WHEN p_grid.
    CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  exporting
   " I_STRUCTURE_NAME =     'TPL_TAB'   " Internal output table structure name
   is_layout          = i_layout          " 属性内表
   it_fieldcat        = i_fieldcat[]      " 列明内表
  tables
    T_OUTTAB                    =      itab.           " Table with data to be displayed
  WHEN p_list.
    CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
  exporting
    "I_STRUCTURE_NAME =     'tpl_tab'  " Internal output table structure name
    is_layout          = i_layout          " 属性内表
    it_fieldcat        = i_fieldcat[]      " 列明内表
  tables
    T_OUTTAB                    =      itab .           " Table with data to be displayed
  WHEN p_write.
    LOOP AT itab INTO wa_data.
      WRITE:/ wa_data-BLDAT, wa_data-BWART,wa_data-WERKS,wa_data-QTY,wa_data-RECNO.
    ENDLOOP.
  WHEN OTHERS.
ENDCASE.

*&---------------------------------------------------------------------*
*&      Form  frm_set_fieldcat
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM frm_set_fieldcat
  USING  l_tabname l_fieldname l_titlename_l l_titlename_s l_fix_column.

  CLEAR  wa_fieldcat.
  wa_fieldcat-tabname     = l_tabname.
  wa_fieldcat-fieldname   = l_fieldname.        " 需要输出的内表的字段名
  wa_fieldcat-seltext_l   = l_titlename_l. " 字段的描述-长字段标签
  wa_fieldcat-seltext_m   = l_titlename_l. " 字段描述-中字段标签
  wa_fieldcat-seltext_s   = l_titlename_s. " 字段描述-短字段标签
  wa_fieldcat-fix_column  = l_fix_column.           " 是否是固定列
  APPEND wa_fieldcat TO i_fieldcat.

ENDFORM.                    " frm_set_fieldcat



再來一支範例，列出指定 Table 的檔案結構(如 ZMM*)

	*&---------------------------------------------------------------------*
*& Report ZMC003
*&---------------------------------------------------------------------*
*& Table Schema From DD03L and DD02T
*&---------------------------------------------------------------------*
REPORT ZMC003.

TYPE-POOLS: slis.

TYPES: BEGIN OF sumReport,
         TABNAME(20) TYPE c,
         TABDESC(100) TYPE c,
         FIELDNAME(20) TYPE c,
         ROLLNAME(20) TYPE c,
         KEYFLAG(1) TYPE c,
         INTTYPE(2) TYPE c,
         INTLEN(10) TYPE c,
       END OF sumReport.

TYPES tpl_tab TYPE STANDARD TABLE OF sumReport WITH DEFAULT KEY.
DATA itab TYPE tpl_tab WITH HEADER LINE.
DATA itab_new TYPE tpl_tab WITH HEADER LINE.
DATA wa_data LIKE LINE OF itab.
DATA git_dfies TYPE STANDARD TABLE OF dfies WITH HEADER LINE.
DATA lc_desc(40) TYPE c.

DATA: wa_fieldcat TYPE slis_fieldcat_alv ,    " 相当于工作区
      i_fieldcat  TYPE slis_t_fieldcat_alv ,  " 存放列名的列表
      i_layout    TYPE slis_layout_alv .      " 负责整个ALV的全局属性

i_layout-zebra                  = 'X' .          " 使ALV界面呈现颜色交替
"i_layout-colwidth_optimize      = 'X' .          " 自动优化列宽
"i_layout-detail_initial_lines   = 'X' .          " 是否出现细节屏幕
"i_layout-detail_titlebar        = '详细内容' .   " 细节屏幕标题

SELECTION-SCREEN  BEGIN  OF  BLOCK  blk1 WITH  FRAME  TITLE  text-001 .
PARAMETERS:
  p_grid RADIOBUTTON GROUP rg1 DEFAULT 'X',
  p_list RADIOBUTTON GROUP rg1,
  p_write RADIOBUTTON GROUP rg1.
SELECTION-SCREEN  END    OF  BLOCK  blk1.

SELECT-OPTIONS:
  c_tbl FOR itab-TABNAME.

START-OF-SELECTION.
  "設定 alv 參數
  PERFORM frm_set_fieldcat  USING:
  'ITAB'  'TABNAME'   'TableName' 'Table'  'X',
  'ITAB'  'TABDESC'   'TableDesc' 'Desc' '',
  'ITAB'  'FIELDNAME'   'FieldName' 'Field' '',
  'ITAB'  'ROLLNAME'   'RollName' 'Roll' '',
  'ITAB'  'KEYFLAG'   'PK' 'PK' '',
  'ITAB'  'INTTYPE'   'Type' 'Type' '',
  'ITAB'  'INTLEN'   'Len' 'Len' ''.

  "取得資料  CAST (10.5 AS INTEGER)
  SELECT DD03L~TABNAME,DD02T~DDTEXT,DD03L~FIELDNAME,DD03L~ROLLNAME,
DD03L~KEYFLAG,DD03L~INTTYPE,DD03L~INTLEN INTO TABLE @itab
    FROM  DD03L LEFT JOIN DD02T ON DD03L~TABNAME = DD02T~TABNAME   
    AND DD02T~DDLANGUAGE = 'M'  "M=ZF SAP
    WHERE DD03L~TABNAME in @c_tbl
    ORDER BY DD03L~TABNAME,DD03L~POSITION.

  " 修改 field desc
  LOOP AT itab INTO wa_data.
    PERFORM frm_get_fielddesc USING wa_data-TABNAME wa_data-FIELDNAME.

    itab_new-TABNAME = wa_data-TABNAME.
    itab_new-TABDESC = wa_data-TABDESC.
    itab_new-FIELDNAME = wa_data-FIELDNAME.
    itab_new-ROLLNAME = lc_desc.
    itab_new-KEYFLAG = wa_data-KEYFLAG.
    itab_new-INTTYPE = wa_data-INTTYPE.
    itab_new-INTLEN = wa_data-INTLEN.

    APPEND itab_new.
  ENDLOOP.

CASE 'X'.
  WHEN p_grid.
    CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  exporting
   " I_STRUCTURE_NAME =     'TPL_TAB'   " Internal output table structure name
   is_layout          = i_layout          " 属性内表
   it_fieldcat        = i_fieldcat[]      " 列明内表
  tables
    T_OUTTAB                    =      itab_new.           " Table with data to be displayed
  WHEN p_list.
    CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
  exporting
    "I_STRUCTURE_NAME =     'tpl_tab'  " Internal output table structure name
    is_layout          = i_layout          " 属性内表
    it_fieldcat        = i_fieldcat[]      " 列明内表
  tables
    T_OUTTAB                    =      itab .           " Table with data to be displayed
  WHEN p_write.
    LOOP AT itab INTO wa_data.
      WRITE:/ wa_data-TABNAME, wa_data-FIELDNAME,wa_data-ROLLNAME,
wa_data-INTTYPE,wa_data-INTLEN.
    ENDLOOP.
  WHEN OTHERS.
ENDCASE.

*&---------------------------------------------------------------------*
*&      Form  frm_set_fieldcat
*&---------------------------------------------------------------------*
FORM frm_set_fieldcat
  USING  l_tabname l_fieldname l_titlename_l l_titlename_s l_fix_column.

  CLEAR  wa_fieldcat.
  wa_fieldcat-tabname     = l_tabname.
  wa_fieldcat-fieldname   = l_fieldname.        " 需要输出的内表的字段名
  wa_fieldcat-seltext_l   = l_titlename_l. " 字段的描述-长字段标签
  wa_fieldcat-seltext_m   = l_titlename_l. " 字段描述-中字段标签
  wa_fieldcat-seltext_s   = l_titlename_s. " 字段描述-短字段标签
  wa_fieldcat-fix_column  = l_fix_column.           " 是否是固定列
  APPEND wa_fieldcat TO i_fieldcat.

ENDFORM.                    " frm_set_fieldcat

*&---------------------------------------------------------------------*
*&      Form  frm_set_fieldcat
*&---------------------------------------------------------------------*
*     這個 issue 撞牆快一天, 只因為引數的型別錯誤, 重點在 line 120-121
*----------------------------------------------------------------------*
FORM frm_get_fielddesc USING  lc_table lc_field.
  DATA ld_tabname   TYPE DDOBJNAME.
  DATA ld_field TYPE DFIES-FIELDNAME.

  ld_tabname = lc_table.
  ld_field = lc_field.

CALL FUNCTION 'DDIF_FIELDINFO_GET'
  EXPORTING
    tabname        = ld_tabname
    fieldname      = ld_field
    langu          = sy-langu
  TABLES
    dfies_tab      = git_dfies[]
  EXCEPTIONS
    not_found      = 1
    internal_error = 2
    OTHERS         = 3.

  IF sy-subrc = 0.
    "Implement suitable error handling here
    LOOP AT git_dfies.
      lc_desc = git_dfies-scrtext_l.
    ENDLOOP.
  ENDIF.
ENDFORM.


呼叫 DDIF_FIELDINFO_GET 這支程式時，我足足被卡住一天，一直鬼打牆，報如下的錯誤
[image: ]


當我終於搞清楚原因，回頭再看這個錯誤訊息，覺得他講得很清楚
 Type conflict during a function module call
就是型別錯誤，但是，一開始我怎麼都沒找到我的型別哪裡錯了?
我一開始的寫法如下
	呼叫端
	PERFORM frm_get_fielddesc USING wa_data-TABNAME wa_data-FIELDNAME.

	程式
	FORM frm_get_fielddesc USING  lc_table lc_field.
 CALL FUNCTION 'DDIF_FIELDINFO_GET'
  EXPORTING
    tabname        = lc_table
    fieldname      = lc_field
    langu          = sy-langu
  TABLES
    dfies_tab      = git_dfies[]


我怎麼看都沒問題啊，但是就是錯，一直說是型別錯誤，後來 Google 半天，
https://www.erpgreat.com/abap/how-to-get-the-field-descriptions-of-a-table.htm  改為
	FORM frm_get_fielddesc USING  lc_table lc_field.
  DATA ld_tabname   TYPE DDOBJNAME.
  DATA ld_field TYPE DFIES-FIELDNAME.

  ld_tabname = lc_table.
  ld_field = lc_field.
 
CALL FUNCTION 'DDIF_FIELDINFO_GET'
  EXPORTING
    tabname        = ld_tabname
    fieldname      = ld_field


真的是型別問題，以後寫程式要看清楚註解
	CALL FUNCTION 'DDIF_FIELDINFO_GET'
  exporting
    TABNAME        =                  " Name of the Table (of the Type) for which Information is Req
*    FIELDNAME      = ' '              " Use Parameter LFIELDNAME Instead
*    LANGU          = SY-LANGU         " Language of the Texts
*    LFIELDNAME     = ' '              " If Filled, only Field with this Long Name
*  tables
*    DFIES_TAB      =                  " Field List if Necessary
*    FIXED_VALUES   =                  " Description of Domain Fixed Values




再新增一支Excel 匯入的範例程式
	*&---------------------------------------------------------------------*
*& Report ZFD006_U02
*&---------------------------------------------------------------------*
*& Description: 特約加盟管控記錄匯入作業
*& Func.Spec  : 三商家購_外掛程式規格書_SP_FI-056~062 加盟分潤系統_擴充報表.doc
*& Author     : Michael Chen
*&=====================================================================*
*& Modification Log - History
*&=====================================================================*
*& Date         Modifier        Request_No     Description
*&---------------------------------------------------------------------*
*& 2012001/06   Michael Chen      DEVK900132     程式建立
*&---------------------------------------------------------------------*
REPORT ZFD006_U02.

TYPE-POOLS: slis.
TYPE-POOLS truxs.

TABLES : ZFD005_T04.

DATA:
      wa_fieldcat TYPE slis_fieldcat_alv ,    " 相当于工作区
      i_fieldcat  TYPE slis_t_fieldcat_alv ,  " 存放列名的列表
      i_layout    TYPE slis_layout_alv .      " 负责整个ALV的全局属性

i_layout-zebra                  = 'X' .          " 使ALV界面呈现颜色交替

TYPES:
  BEGIN OF t_tab,
    BUKRS(4)  type c,
    WERKS(8)  type c,
    ZBUPER(6) type  c,
    ZCTRL_SCORE type I,
    ZCTRL_MEMO(60) type c,
  END OF t_tab.

DATA :
  t_upload TYPE STANDARD TABLE OF t_tab,
  wa_upload TYPE t_tab,
  it_type TYPE truxs_t_text_data.

DATA:
      recno type I,
      ok_no type I,
      err_no type I.

DATA: ok_c(10) TYPE c, err_c(10) TYPE c.
DATA: lv_result(200) TYPE c.

* Selection screen
SELECTION-SCREEN  BEGIN  OF  BLOCK  blk1 WITH  FRAME  TITLE  text-001 .
PARAMETERS:
  p_view RADIOBUTTON GROUP rg1 DEFAULT 'X',
  p_save RADIOBUTTON GROUP rg1.
SELECTION-SCREEN  END    OF  BLOCK  blk1.

SELECTION-SCREEN  BEGIN  OF  BLOCK  blk2 WITH  FRAME  TITLE  text-002 .
  PARAMETERS p_file TYPE rlgrap-filename DEFAULT 'D:\Data\ZFD005_T04.xlsx'.
SELECTION-SCREEN  END    OF  BLOCK  blk2.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  CALL FUNCTION 'F4_FILENAME'
  EXPORTING
    field_name = 'P_FILE'
  IMPORTING
    file_name = p_file.

START-OF-SELECTION.
* Uploading the data in the file into internal table
  CALL FUNCTION 'TEXT_CONVERT_XLS_TO_SAP'
  EXPORTING
* I_FIELD_SEPERATOR =
* I_LINE_HEADER = 'X'
  i_tab_raw_data = it_type
  i_filename = p_file
  TABLES
  i_tab_converted_data = t_upload[]
  EXCEPTIONS
  conversion_failed = 1
  OTHERS = 2.

  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid
    TYPE sy-msgty
    NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  CASE 'X'.
  WHEN p_view.
    PERFORM frm_view.
  WHEN p_save.
    PERFORM frm_save.
  WHEN OTHERS.
  ENDCASE.

END-OF-SELECTION.

*&---------------------------------------------------------------------*
*&      Form  frm_view
*&---------------------------------------------------------------------*
FORM frm_view.
  "設定 alv 參數
  PERFORM frm_set_fieldcat  USING:
  't_upload'  'BUKRS'   '公司代碼' '公司代碼'  'X',
  't_upload'  'WERKS'   '工廠' '工廠' '',
  't_upload'  'ZBUPER'   '年月(YYYYMM)' '年月' '',
  't_upload'  'ZCTRL_SCORE'   '點檢分數' '點檢分數' '',
  't_upload'  'ZCTRL_MEMO'   '缺失紀錄' '缺失紀錄' ''.

  "顯示 excel 內容
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
  exporting
   " I_STRUCTURE_NAME =     'TPL_TAB'   " Internal output table structure name
   is_layout          = i_layout          " 属性内表
   it_fieldcat        = i_fieldcat[]      " 列明内表
  tables
    T_OUTTAB                    =      t_upload.           " Table with data to be displayed
ENDFORM.

*&---------------------------------------------------------------------*
*&      Form  frm_view
*&---------------------------------------------------------------------*
*& 目前版本沒有防錯機制, 應該要加入檢查及是否已存在的判斷
*&---------------------------------------------------------------------*
FORM frm_save.
* Uploading the data into the database table
  ok_no = 0.
  err_no = 0.
  LOOP AT T_UPLOAD INTO WA_UPLOAD.
    "判斷資料是否已存在, 若已存在 skip
    select count( * ) into @recno from ZFD005_T04 where BUKRS = @WA_UPLOAD-BUKRS and WERKS = @WA_UPLOAD-WERKS  and ZBUPER = @WA_UPLOAD-ZBUPER.

    if recno = 0.
      ZFD005_T04-BUKRS = WA_UPLOAD-BUKRS.
      ZFD005_T04-WERKS = WA_UPLOAD-WERKS.
      ZFD005_T04-ZBUPER = WA_UPLOAD-ZBUPER.
      ZFD005_T04-ZCTRL_SCORE = WA_UPLOAD-ZCTRL_SCORE.
      ZFD005_T04-ZCTRL_MEMO = WA_UPLOAD-ZCTRL_MEMO.

      MODIFY ZFD005_T04.
      ok_no = ok_no + 1.
    else.
      err_no = err_no + 1.
    endif.
  ENDLOOP.

  ok_c = ok_no.
  err_c = err_no.
  CONCATENATE '資料寫入成功筆數:' ok_c '，失敗筆數:' err_c INTO lv_result.
  CALL FUNCTION 'POPUP_TO_DISPLAY_TEXT'
     exporting
       TEXTLINE1    =  lv_result.
ENDFORM.

*&---------------------------------------------------------------------*
*&      Form  frm_set_fieldcat
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM frm_set_fieldcat
  USING  l_tabname l_fieldname l_titlename_l l_titlename_s l_fix_column.

  CLEAR  wa_fieldcat.
  wa_fieldcat-tabname     = l_tabname.
  wa_fieldcat-fieldname   = l_fieldname.        " 需要输出的内表的字段名
  wa_fieldcat-seltext_l   = l_titlename_l. " 字段的描述-长字段标签
  wa_fieldcat-seltext_m   = l_titlename_l. " 字段描述-中字段标签
  wa_fieldcat-seltext_s   = l_titlename_s. " 字段描述-短字段标签
  wa_fieldcat-fix_column  = l_fix_column.           " 是否是固定列
  APPEND wa_fieldcat TO i_fieldcat.

ENDFORM.                    " frm_set_fieldcat





Session 2：ABAP 資料表_事物碼(T-Code)資訊
https://www.fenginfo.com/472.html
Session 2.1：說明
SAP的事物碼（Transaction Code，簡寫T-CODE）相關資訊存放在三張表（Table）中：
· 資料表TSTC存放T-CODE的關聯程式、螢幕資訊
· 資料表TSTCP存放相關參數，如變式名稱及賦值等
· 資料表TSTCT存放語言文本，為多種語言翻譯服務
以上各表均可用SE11、SE16N查詢結構及資料。

T-CODE表的資訊是cross-client級別的，一套ERP系統下各Client之間T-CODE的數量及相關資訊均相同。
Session 2.2：表說明
1．資料表TSTC
中文名稱：SAP 事務代碼
類型：轉帳表，全部欄位見下
	欄位名
	主鍵
	類型
	說明

	TCODE
	Y
	CHAR(20)
	事務代碼

	PGMNA
	
	CHAR(40)
	程式名稱

	DYPNO
	
	NUMC(4)
	螢幕號碼

	MENUE
	
	CHAR(5)
	SYST的CHAR05資料元素

	CINFO
	
	RAW(1)
	SYST 之HEX01 資料元素

	ARBGB
	
	CHAR(20)
	消息識別


2．資料表TSTCP，中文名稱：事務參數
	欄位名
	主鍵
	類型
	說明

	TCODE
	Y
	CHAR(20)
	事務代碼

	PARAM
	
	CHAR(254)
	事務的參數


3．資料表TSTCT
中文名稱：事務代碼文本
類型：轉帳表，全部欄位見下
	欄位名
	主鍵
	類型
	說明

	SPRSL
	Y
	LANG(1)
	語言代碼

	TCODE
	Y
	CHAR(20)
	事務代碼

	TTEXT
	
	CHAR(36)
	事務說明





Session 3：查看事物碼相關的資料物件
https://www.fenginfo.com/2747.html
隨著對業務的深入，作為諮詢顧問很多時候需要知道業務涉及的資料表，如果想知道某個事物碼涉及的資料表名稱，可先用SE93進行查看，大致分為兩種情況：
· 事物碼是綁定的程式，查看程式的涉及物件就可找到涉及的資料表。
· 事物碼是綁定的視圖或視圖族，查看表結構可以看到涉及的資料表。
以查看ME2L為例，前臺執行SE93，進入後如圖 1所示，輸入事物碼ME2L，並點擊“顯示”按鈕。
[image: https://img.fenginfo.com/blog/02747/image001.jpg]
進入後顯示事物碼對應的程式資訊，如下圖所示，注意這裡的程式條目值“RM06EL00”和選擇螢幕條目值“1000”，兩個條目都可以點擊進入ABAP編輯介面，前者程式也可用SE38進入後查看，後者螢幕也可用SE51進入後查看。
[image: https://img.fenginfo.com/blog/02747/image002.jpg]
以查看程式為例，如圖 3所示顯示程式的代碼，在工具列點擊“顯示物件清單”按鈕（[image: https://img.fenginfo.com/blog/02747/bt1.jpg] ）。
[image: https://img.fenginfo.com/blog/02747/image003.jpg]
介面的右邊出現導向條形功能表，在“資源庫流覽器”條形功能表下，有此程式的關聯物件，其中在“字典結構”下可以看到程式涉及到的資料表。
[image: https://img.fenginfo.com/blog/02747/image004.jpg]
對於配置類的基於SM30維護視圖、SM34維護視圖所生成的事物碼，如OX18（為工廠分配公司代碼），用SE93進入後介面如圖 5所示，其事務為SM30，底部缺省值條目“VIEWNAME”的值為“V_T001K_Assign”,這就是維護視圖的名稱。
[image: https://img.fenginfo.com/blog/02747/image005.jpg]


前台執行SE11查看視圖V_T001K_Assign的結構，在“表/連接條目”標籤頁下，左側有多個資料表，這就是配置涉及的表名，其中第一個“T001K”是資料維護的主表，其它表則是輔助表，很多輔助表只是用來顯示附加的描述資訊。SM30維護視圖也涉及程式，相關資訊參見《自訂SM30維護視圖》、《為維護視圖創建事物碼(Transaction code)》。
[image: https://img.fenginfo.com/blog/02747/image006.jpg]
圖 6 SE11查看視圖資訊_表/連接條件標籤頁



關於表單的 Enhanse 介面的設定
後勤系統-一般-物料主檔-零售特定的設定-特定零售 Business Add-In 下有3個 Bapi
[image: ]
所有物料主檔的相關的擴充程式，都是在此建立修改。此處為進階內容，稍有了解即可。
[image: ]

接下來繼續設定
[image: ]

啟用零售業的相關元件
[image: ]
DC的參考工廠和商店的參考工廠，等於是範本的建立，當要建立物流(或央廚)、門店時，會依據此處設定的代號執行複製 Site 的範本功能。不建議用一個既有以實際存在的 Site 為範本(雖然也可以)。



· 關於 Change Request(CR) 及 SE10及STMS 的說明
  開發程式時，不管使用哪一個 Development Tools，都一定有一個議題要特別關注，那就是版本管理。尤其是多人同時開發，且又使用共用 Library 底層的情況。SAP ABAP 是一種類似直譯式的程式語言，他的 Source Code 推測應該是存放在 DataBase 中，他是透過 Change Request(以下簡稱 CR) 來做版本管理，並透過 DEVQASPROD的環境建置及一組 T-Code，就能完整的執行包括新版本的測試及發佈等作業。以下簡單的說明主要的操作及概念。
  完整的說明，可以參考 Michael 顧問的四天上課課程(含講義)，內容說明非常清楚。
\\10.0.8.14\sap導入專案\專案公用資料夾\Phase 1 專案準備\1.X 影音檔\ABAP\
\\10.0.8.14\sap導入專案\專案公用資料夾\Phase 1 專案準備\1.4 SAP ERP 功能教育訓練\ABAP

  下圖摘自講義，是 ABAP 執行的完整流程
[image: ]



· Data Structure Of SAP ERP System
[image: ]
· 相關常用的 T-Code(開發相關)
[image: ]


· Change Request
· 當新增程式，或是修改程式時，系統會談出下列視窗，請選擇一個 CR Code，如果是新的版號，請按右下角的新增。
[image: ]
· 也可查詢目前帳號還有哪些進行中的 CR
[image: ]


· 輸入說明後按存檔，會自動產生一個新的 CR Code(版本代號)
[image: ]
[image: ]
· 上面這個作業類似版控軟體的 Check Out作業，只要在本程式沒有執行 SE10 的發佈 [貨車 Transfer ] 功能前(類似 Check In)，可以持續修改程式。
· SE10
· 執行 T-Code SE10，準備將程式由 DEV發佈到 QAS，此時是要先登入 DEV (執行匯出)
注意原則，一定必須要由下往上執行 Transfer(核發)，先點選 DEVK904188 按 [核發]，再點選 DEVK904187 再按 [核發]。
[image: ]
· 當執行 4188 的核發後，會出現下列訊息
[image: ]
[image: ]
· 當 4187 核發後(全部程式)，出現下列的訊息
[image: ]
· STMS
· 接下來，請重新登入 QAS，準備執行匯入作業，先按下貨車 button，再選 QAS
[image: ]
[image: ]
· 先按 Refresh，才會看到剛才由 DEV 傳過來的 CR
[image: ]

[image: ]
· 執行匯入，請務必要輸入目標用戶端的內容，我的 QAS 是540(Client)。
[image: ]


· 按確定，會出現提示，再按 [是]，稍後等狀態變為綠燈即完成
[image: ]

[image: ]
· 曾發生的 issue：因為我一開始開發沒有搞清楚應該先 DEVQASPROD 的更新順序，而是直接在 QAS 開發，所以是先有 QAS 的程式，後有 QAS 的程式(相同程式名稱)，當我執行上面的作業時，會報錯(紅燈) 訊息看不太懂。後來就直接更新程式名稱，重新再來一次，就全部正常。
· T-Code 閃退問題 https://linhuang.blog.csdn.net/article/details/101083774
原因：TCODE配置錯了！
如圖，正常我們創建TCODE，一般的report選擇的是第二個，預設螢幕是自動生成的1000螢幕，而dialog的TCODE選第一個，螢幕號給自建螢幕(非1000)，而這邊他創建時候選的第一個，還分配了1000螢幕。。。So
解決辦法：重新創建個TCODE：選第二個，問題解決。
[image: https://img-blog.csdnimg.cn/20190920233617220.png?x-oss-process=image/watermark,type_ZmFuZ3poZW5naGVpdGk,shadow_10,text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2h1YW5nbGluNg==,size_16,color_FFFFFF,t_70]


· 使用SE80指定程式的 T-Code
· 選擇 [程式] 及程式名稱(ZU_SCHEMA)
[image: ]
· 在程式名稱上按右鍵-建立-交易
[image: ]
· 輸入下列資訊
[image: ]

· 輸入程式名稱後按存檔
[image: ]
· 再輸入開發類別(Package)，可以開窗查詢自行選擇所屬的 Package
[image: ]
· 新增或選擇正確的 CR 代號，然後確定即可。
[image: ]
· 螢幕左下角會顯示操作正確的訊息
[image: ]
· 輸入 ZUSMA 這個 T-Code
[image: ]
· 即可正確的執行
[image: ]


· 與SAP資料整合的常用方式
IDOC、BAPI、RFC 差別
https://www.itread01.com/content/1546822276.html
https://www.stechies.com/difference-between-rfc-bapi/

· SAP 的資料整合方式主要有RFC、IDOC、BAPI三種。
· RFC分二種：1 正常的本地RFC。2 遠端RFC(外部系統調用)。
SE37寫出來的叫function,其中可以遠端呼叫的叫RFC，Remote-enabled Function Call，abap語法和輸入輸出引數就會有一些限制。
· BAPI（SAP自帶業務函數--封裝好函數）。
RFC和BAPI 都可以理解成一個函數。它有輸入、輸出，改變，排除 參數，表(既可以輸入也輸出)。一般都用在同步、線上的即時作業。
· IDOC是基於sap自己的類似xml格式的文件資料交換的方式。因為是文件格式，所以一般是非及時、非同步的。
· 三種方式的差異
· RFC是面向過程的，呼叫簡單直接；
· BAPI是面向物件的，有屬性、有方法、有事件，更加複雜和豐富，更能反映SAP的業務應用，而
BAPI方法的構造是基於RFC的，你也可以認為BAPI封裝了RFC，RFC在應用時更為靈活。
· IDOC是SAP標準的檔案交換格式，SAP已經有了大量的Function Module來處理和傳遞IDOC，特別是對於要和其它系統交換資料時，配合一些系統如biztalk server，IDOC會顯得非常的方便，開發的工作量也是最小的(不過目前我還沒有實際的開發經驗，所以只能先聽聽)。
· 應該說RFC是其它內容的基礎，它是一個Function module，可以被遠端呼叫。而BAPI本身就是一
個RFC，但它被作為BO的Interface，作用更進一步，除了BAPI文件中提到的內容外，還可以作為
ALE/IDOC的開發基礎。
ALE是R/3系統之間的應用層資料交換，至於用什麼，就看具體配置了，比如可以用IDOC，同步／
非同步BAPI，甚至用EDI。非SAP系統無法用ALE來實現。
至於資料傳輸的方式，可以是IDOC（底層是用RFC來實際的），也可以是EDI，所以說IDOC／EDI實
際上是資料的載體。
以上是關於RFC、BAPI及IDOC的簡單說明，基本上在ABAP程式中，RFC當然是一切程式庫(Library)的基礎。我們先了解在SAP中有提供這些呼叫的方式，先由熟悉使用現有的程式為開始，等到更熟悉相關的技術後，再深入研究。這個部分屬於較進階的範圍，本文先不多做說明。可以在ABAP的介紹章節中，參考範例程式的寫法。


· BAPI  由外部呼叫SAP的流程
[image: BAPI Diagram]
· RFC VS BAPI
[image: Difference Between RFC and BAPI in SAP - Comparison Summary]

